**MAİL GÖNDERME**

**MAİL GÖNDERME**

Mail göndermek için CL\_BCS sınıfı kullanılır. Bunun dışında aşağıdaki eski fonkiyonlar kullanılabilir ancak 6.10 versiyonundan sonra kullanılması önerilmez. CL\_BCS sınıfı eski fonksiyonlara göre daha fazla seçenek ve esneklik sunar.

CL\_BCS sınıfı ile aşağıdaki sınıftan nesne oluşturularak ve yöntemler kullanılarak basit şekilde mail gönderimi yapılabilir.

|  |  |  |  |
| --- | --- | --- | --- |
| **Sınıf / Nesne** | **Metod/nesne** | **Tip** | **Anlamı** |
| cl\_bcs | create\_persistent | nesne | Gönderim isteği nesnesi oluşturur. |
| cl\_document\_bcs | create\_document | nesne | Mail içeriği nesnesi oluşturur. |
| gonderim\_istegi | set\_document | yöntem | Dökümanı gönderi isteğine ekler. |
| cl\_sapuser\_bcs | create | nesne | Mail gönderen kişi nesnesini oluşturur. |
| gonderim\_istegi | set\_sender | yöntem | Gönderi isteğine göndereni ekleyen yöntem. |
| cl\_cam\_address\_bcs | create\_internet\_address | nesne | Alıcı nesnesi oluşturur. |
| gonderim\_istegi | add\_recipient | yöntem | Gönderi isteğine alıcı ekler. |
| gonderim\_istegi | send | yöntem | Gönderi isteğini gerçekleştirir. |

Mail özellikleri (mesaj içeriği, alıcı ve gönderen, ek,…) tanımlandıktan sonra mail gönderim işlemi yapılabilir. Gönderilen mailler SAPconnect tarafından toplanır ve belirli periyotta gönderilir. Gönderim periyodu SAPconnect içerisinde bir defa konfigüre edilir. Gönderim işlemi SCOT işlem kodu ile gönderi zamanını beklemeden başlatılabileceği gibi RSCONN01 programı kullanılarak da çalıştırılabilir.

Gönderim periyodunu beklemeden mailin gönderilmesi için CL\_BCS sınıfındaki set\_send\_immediately yöntemi kullanılabilir.

Mail göndermek için kullanılan eski fonksiyonlar şunlardır.

· SO\_NEW\_DOCUMENT\_SEND\_API1

· SO\_NEW\_DOCUMENT\_ATT\_SEND\_API1

· SO\_DOCUMENT\_SEND\_API1

· SO\_OBJECT\_SEND

**MAIL GÖNDERME ÖRNEKLERİ**

1. CL\_BCS sınıfı kullanılarak SPFLI tablosundaki bazı sütunları mail gönderen örnek. [alankisi@abcdef.com](mailto:alankisi@abcdef.com) kısmına mail gönderilmek istenen kişinin mail adresi yazılmalıdır.

DATA: gs\_spfli TYPE spfli.  
DATA: go\_gonderim\_istegi TYPE REF TO cl\_bcs,  
gt\_mailicerigi     TYPE STANDARD TABLE OF soli,  
gs\_mailicerigi     TYPE soli,  
go\_mailbelgesi     TYPE REF TO cl\_document\_bcs,  
go\_gonderen        TYPE REF TO cl\_sapuser\_bcs,  
go\_alicibilgileri  TYPE REF TO if\_recipient\_bcs,  
go\_bcs\_istisna     TYPE REF TO cx\_bcs,  
gv\_sent\_to\_all     TYPE os\_boolean.  
gs\_mailicerigi = ‘SPFLI Tablo içeriği aşağıdaki gibidir.’.  
APPEND gs\_mailicerigi TO gt\_mailicerigi.  
SELECT \* FROM spfli INTO gs\_spfli UP TO 10 ROWS.  
CLEAR gs\_mailicerigi.  
CONCATENATE gs\_spfli-carrid   gs\_spfli-connid gs\_spfli-countryfr  
gs\_spfli-cityfrom gs\_spfli-airpfrom  
INTO gs\_mailicerigi SEPARATED BY space.  
APPEND gs\_mailicerigi TO gt\_mailicerigi.  
ENDSELECT.  
TRY.  
go\_gonderim\_istegi = cl\_bcs=>create\_persistent( ).  
go\_mailbelgesi = cl\_document\_bcs=>create\_document(  
i\_type    = ‘RAW’  
i\_text    = gt\_mailicerigi  
i\_subject = ‘Örnek CL\_BCS Sınıfı Mail Gönderimi’ ).  
CALL METHOD go\_gonderim\_istegi->set\_document( go\_mailbelgesi ).  
go\_gonderen = cl\_sapuser\_bcs=>create( sy-uname ).  
CALL METHOD go\_gonderim\_istegi->set\_sender  
EXPORTING  
i\_sender = go\_gonderen.  
go\_alicibilgileri = cl\_cam\_address\_bcs=>create\_internet\_address(  
‘alankisi@abcdef.com’ ).  
CALL METHOD go\_gonderim\_istegi->add\_recipient  
EXPORTING  
i\_recipient = go\_alicibilgileri  
i\_express   = ‘X’.  
CALL METHOD go\_gonderim\_istegi->send(  
EXPORTING  
i\_with\_error\_screen = ‘X’  
RECEIVING  
result              = gv\_sent\_to\_all ).  
IF gv\_sent\_to\_all = ‘X’.  
COMMIT WORK.  
WRITE ‘Mail gönderildi.’.  
ENDIF.  
CATCH cx\_bcs INTO go\_bcs\_istisna.  
WRITE: ‘Hata oluştu!’, go\_bcs\_istisna->error\_type.  
EXIT.  
ENDTRY.

2. Eski SO\_NEW\_DOCUMENT\_SEND\_API1 fonksiyonu kullanarak mail gönderen örnek.

DATA   : gt\_alicibilgileri  TYPE STANDARD TABLE OF somlreci1,  
gs\_alicibilgileri  TYPE somlreci1,  
gt\_mailicerigi     TYPE STANDARD TABLE OF solisti1,  
gs\_mailicerigi     TYPE solisti1,  
gs\_mailozellikleri TYPE sodocchgi1.  
\* Mail alıcıları  
gs\_alicibilgileri-receiver = ‘alankisi@abcdef.com’.  
gs\_alicibilgileri-rec\_type = ‘U’.  
APPEND gs\_alicibilgileri TO gt\_alicibilgileri.  
\* Mailin Konu kısmı ve özellikleri  
gs\_mailozellikleri-obj\_langu  = ‘T’.  
gs\_mailozellikleri-obj\_name   = ‘Mesaj’.  
gs\_mailozellikleri-obj\_descr  = ‘Örnek Mail Gönderimi!’.  
\*Mailin içeriği dahili tabloya ekleniyor  
gs\_mailicerigi-line = ‘Mail içeriği’.  
APPEND gs\_mailicerigi TO gt\_mailicerigi.  
\* Mail gönderme fonksiyonu  
CALL FUNCTION ‘SO\_NEW\_DOCUMENT\_SEND\_API1′  
EXPORTING  
document\_data                    = gs\_mailozellikleri  
commit\_work                      = ‘X’  
TABLES  
object\_content                   = gt\_mailicerigi  
receivers                        = gt\_alicibilgileri  
EXCEPTIONS  
too\_many\_receivers               = 1  
document\_not\_sent                = 2  
document\_type\_not\_exist          = 3  
operation\_no\_authorization       = 4  
parameter\_error                  = 5  
x\_error                          = 6  
enqueue\_error                    = 7  
OTHERS                           = 8.  
IF sy-subrc <> 0.  
MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno  
WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.  
ENDIF.

3. Eski SO\_DOCUMENT\_SEND\_API1 fonksiyonu kullanılarak HTML içeriği olan bir mail gönderim örneği. Mailin mesaj kısmına iki sütundan oluşan html tablo ekler.


DATA: gt\_alicibilgileri  TYPE STANDARD TABLE OF somlreci1,  
gs\_alicibilgileri  TYPE somlreci1,  
gt\_mailicerigi     TYPE STANDARD TABLE OF solisti1,  
gs\_mailicerigi     TYPE solisti1,  
gt\_icerikbilgileri TYPE STANDARD TABLE OF sopcklsti1,  
gs\_icerikbilgileri TYPE sopcklsti1,  
gs\_mailozellikleri TYPE sodocchgi1,  
gv\_gonderen        TYPE soextreci1-receiver VALUE ‘gonderen@abcdef.com’.  
\* Mail alıcıları  
gs\_alicibilgileri-receiver = ‘alankisi@abcdef.com’.  
gs\_alicibilgileri-rec\_type = ‘U’.  
APPEND gs\_alicibilgileri TO gt\_alicibilgileri.  
\* Mailin Konu kısmı ve özellikleri  
gs\_mailozellikleri-obj\_langu  = ‘T’.  
gs\_mailozellikleri-obj\_name   = ‘Mesaj’.  
gs\_mailozellikleri-obj\_descr  = ‘Örnek HTML Mail Gönderimi’.  
\*Mailin içeriği dahili tabloya ekleniyor.  
gs\_mailicerigi-line = ‘<p>’.  
APPEND gs\_mailicerigi TO gt\_mailicerigi.  
gs\_mailicerigi-line = ‘HTML Tablo Örneği’.  
APPEND gs\_mailicerigi TO gt\_mailicerigi.  
gs\_mailicerigi-line = ‘</p>’.  
APPEND gs\_mailicerigi TO gt\_mailicerigi.

\*HTML tablo ekleniyor  
gs\_mailicerigi-line = ‘<table border=”1″ width=”100%” id=”table2″>’.  
APPEND gs\_mailicerigi TO gt\_mailicerigi.  
gs\_mailicerigi-line = ‘<tr>’.  
APPEND gs\_mailicerigi TO gt\_mailicerigi.  
gs\_mailicerigi-line = ‘<td>Başlık Sütunu 1</td>’.  
APPEND gs\_mailicerigi TO gt\_mailicerigi.  
gs\_mailicerigi-line = ‘<td>Başlık Sütunu 2</td>’.  
APPEND gs\_mailicerigi TO gt\_mailicerigi.  
gs\_mailicerigi-line = ‘</tr>’.  
APPEND gs\_mailicerigi TO gt\_mailicerigi.  
gs\_mailicerigi-line = ‘<tr>’.  
APPEND gs\_mailicerigi TO gt\_mailicerigi.  
gs\_mailicerigi-line = ‘<td>İçerik Sütunu 1</td>’.  
APPEND gs\_mailicerigi TO gt\_mailicerigi.  
gs\_mailicerigi-line = ‘<td>İçerik Sütunu 2</td>’.  
APPEND gs\_mailicerigi TO gt\_mailicerigi.  
gs\_mailicerigi-line = ‘</tr>’.  
APPEND gs\_mailicerigi TO gt\_mailicerigi.  
gs\_mailicerigi-line = ‘</TABLE>’.  
APPEND gs\_mailicerigi TO gt\_mailicerigi.  
\* Veri tablosu bilgileri  
gs\_icerikbilgileri-transf\_bin = space.  
gs\_icerikbilgileri-head\_start = 1.  
gs\_icerikbilgileri-head\_num   = 0.  
gs\_icerikbilgileri-body\_start = 1.  
DESCRIBE TABLE gt\_mailicerigi LINES gs\_icerikbilgileri-body\_num.  
gs\_icerikbilgileri-doc\_type   = ‘HTM’.  
APPEND gs\_icerikbilgileri TO gt\_icerikbilgileri.  
CALL FUNCTION ‘SO\_DOCUMENT\_SEND\_API1′  
EXPORTING  
document\_data              = gs\_mailozellikleri  
commit\_work                = ‘X’  
sender\_address             = gv\_gonderen  
sender\_address\_type        = ‘INT’  
TABLES  
packing\_list               = gt\_icerikbilgileri  
contents\_txt               = gt\_mailicerigi  
receivers                  = gt\_alicibilgileri  
EXCEPTIONS  
too\_many\_receivers         = 1  
document\_not\_sent          = 2  
document\_type\_not\_exist    = 3  
operation\_no\_authorization = 4  
parameter\_error            = 5  
x\_error                    = 6  
enqueue\_error              = 7  
OTHERS                     = 8.  
IF sy-subrc <> 0.  
MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno  
WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.  
ENDIF.

**Gönderilen Maillerin Kontrolü**

SOST işlem kodu ile SAP sisteminden gönderilen mailleri kontrol edilebilir. Kontrol etmek için,

1. SOST işlem koduna girilir.



**Period** tabında gönderim tarihi (send date) bilgileri doldurulur. **Send status** tabında tüm seçenekler seçilir ve **Refresh** butona tıklanır. Yenilenen listede gönderilen mailler görülebilir.


Bir mailin içeriğini görüntülemek için listeden seçtikten sonra görüntüle (C:\Users\grencuz\Desktop\içerik.png ) butonuna tıklanması yeterlidir.




**SAPconnect Ayarlarının Kontrolü**

Mail göndermek için SAPconnect mail konfigürasyonunun daha önceden yapılmış olması gerekir. Aşağıdaki adımlarla SAPconnect ayarlarını kontrol edebilirsiniz.

1. SCOT işlem koduna çalıştırılır.



2. SMTP yazısına çift tıklanır.




3. Mail adresi, port numarası ve mail gönderme periyodunun doldurulmuş olması gerekir. **Node in use** tıklanmış ve **Supported address types** kısmında **Internet** tıklı ise mail ayarları yapılmış demektir. **Hours/minutes** girilen periyoda göre mail gönderimi gerçekleştirilir.

**Gönderim Periyoduna Bağlı Olmadan Mail Gönderme İşlemininin Başlatılması**


Mailler SAPconnect içerisinde tanımlanan periyoda göre gönderilir. Eğer bu periyodu beklemek istemiyorsanız SAPconnect Administration (SCOT) ile mail gönderimini hemen başlatabilirsiniz.

1. SCOT işlem koduna girilir.




2. SMTP yazısına tıklanır ve araç çubuğunda en sağdaki Start send process <IMG border=0 src=”file:///C:\Users\iuyanik\AppData\Local\Temp\msohtmlclip1\01\clip\_image013.jpg” width=20 height=20 v:shapes=””> ikonu (veya Ctrl+F7) tıklanır.

3. Açılan ekranda Start butonu tıklanır.



Eğer bekleyen mesaj var ise yeni bir ekran açılır ve gönderilen maillerin bilgileri görüntülenir.



Gönderilecek mesaj yok ise **No messages sent** mesajı çıkar

C:\Users\grencuz\Desktop\içerik.png